Układ na moteino zawiesza się przy wachaniach temperatury

dogu18 · Post Fri Sep 18, 2020 8:46 pm

Witam
Posiadam czujnik na moteino i bramkę na wemos. Czujnik wyposażony w dme280 i bh1750 jest zamknięty w szczelnej obudowie na zewnątrz.
Problem jest taki ze jak zmienia się temperatura (rano lub wieczorem) czujnik się zawiesza i nie wysyła danych.
Gdy stoi w pokoju działa idealnie niestety po wystawieniu na zewnątrz zawiesza się.
Zasilanie jest z ogniwa 18650

co może być przyczyną?? wilgoć już wykluczyłem

Pozdrawiam serdecznie

QLQ · Post Sat Sep 19, 2020 5:33 am

dogu18 wrote: Fri Sep 18, 2020 8:46 pm Witam
Posiadam czujnik na moteino i bramkę na wemos. Czujnik wyposażony w dme280 i bh1750 jest zamknięty w szczelnej obudowie na zewnątrz.
Problem jest taki ze jak zmienia się temperatura (rano lub wieczorem) czujnik się zawiesza i nie wysyła danych.
Gdy stoi w pokoju działa idealnie niestety po wystawieniu na zewnątrz zawiesza się.
Zasilanie jest z ogniwa 18650

co może być przyczyną?? wilgoć już wykluczyłem

Pozdrawiam serdecznie

Problem może być z czujnikiem BME lub BH ( ale raczej ten pierwszy) mi na początku padły trzy. Czwarty teraz działa od około 9 miesięcy.
ALe takiego objawu j/w nie miałem. Pokazywały cały czas 100 wilgotności, temp natomiast chodziła prawidłowo. BME ma otwór może tam dostała się woda i jak znów jest na dworze gdy wilgotność wzrasta robi zwarcie

dogu18 · Post Tue Sep 22, 2020 1:57 pm

QLQ wrote: Sat Sep 19, 2020 5:33 am
dogu18 wrote: Fri Sep 18, 2020 8:46 pm Witam
Posiadam czujnik na moteino i bramkę na wemos. Czujnik wyposażony w dme280 i bh1750 jest zamknięty w szczelnej obudowie na zewnątrz.
Problem jest taki ze jak zmienia się temperatura (rano lub wieczorem) czujnik się zawiesza i nie wysyła danych.
Gdy stoi w pokoju działa idealnie niestety po wystawieniu na zewnątrz zawiesza się.
Zasilanie jest z ogniwa 18650

co może być przyczyną?? wilgoć już wykluczyłem

Pozdrawiam serdecznie
Problem może być z czujnikiem BME lub BH ( ale raczej ten pierwszy) mi na początku padły trzy. Czwarty teraz działa od około 9 miesięcy.
ALe takiego objawu j/w nie miałem. Pokazywały cały czas 100 wilgotności, temp natomiast chodziła prawidłowo. BME ma otwór może tam dostała się woda i jak znów jest na dworze gdy wilgotność wzrasta robi zwarcie

dzieki.
podmienimiłem BME i jk na razie działa, niestety w nocy pokazuje 100% wilgotności ale zamówiłem nowy czujnik.

mam też problem ze zmianą typu czujnika w bramce zamiast czujnika dystansu chciał bym temperatury jakoś nie potrafię.
mogę prosić o pomoc??

Code: Select all

/*
Bramka RB-10G
Copyright (C) 2019 Robert Błaszczak

Niniejszy program jest wolnym oprogramowaniem; możesz go 
rozprowadzać dalej i/lub modyfikować na warunkach Powszechnej
Licencji Publicznej GNU, wydanej przez Fundację Wolnego
Oprogramowania - według wersji 2-giej tej Licencji lub którejś
z późniejszych wersji. 
Niniejszy program rozpowszechniany jest z nadzieją, iż będzie on 
użyteczny - jednak BEZ JAKIEJKOLWIEK GWARANCJI, nawet domyślnej 
gwarancji PRZYDATNOŚCI HANDLOWEJ albo PRZYDATNOŚCI DO OKREŚLONYCH 
ZASTOSOWAŃ. W celu uzyskania bliższych informacji - Powszechna 
Licencja Publiczna GNU. 
Z pewnością wraz z niniejszym programem otrzymałeś też egzemplarz 
Powszechnej Licencji Publicznej GNU (GNU General Public License);
jeśli nie - napisz do Free Software Foundation, Inc., 675 Mass Ave,
Cambridge, MA 02139, USA.
*/

#include <RFM69_ATC.h>                    //Pobierz z: https://github.com/lowpowerlab/rfm69
#include <DallasTemperature.h>

#define NODEID 1                          //Unikalny numer bramki (1 - 254).
#define NETWORKID 100                     //Numer sieci (1 - 254) w której działą bramka SUPLA oraz inne transmitery. Bramka oraz max. 6 transmiterów musi działać w sieci o takim samym ID.
#define FREQUENCY RF69_868MHZ             //Jeśli posiadasz moduł radiowy pracujący z inną częstotliwością zamień parametr na RF69_433MHZ lub RF69_915MHZ.
//#define IS_RFM69HW_HCW                  //Usuń zacznik komentarza, jeśli posiadasz moduł radiowy w wersji RFM69HW/HCW.
#define ENCRYPTKEY "qwertyuiopasdfgh"     //Klucz kodowania - 16 znaków (ani mniej, ani więcej) - identyczny w bramce SUPLA i we wszystkich transmiterach.
#define ENABLE_ATC                        //Wstaw znacznik komentarza jeśli chcesz wyłączyć automatyczną kontrolę transmisji (ATC).

#define SERIAL_BAUD 115200                //Prędkość transmisji portu szeregowego.

#define SUPLADEVICE_CPP
#include <SuplaDevice.h>

#define SUPLA_SERVER "svr8.supla.org"
#define LOCATION_ID 2641
#define LOCATION_PASSWORD "cd76"
// pobierz identyfikator urządzenia ze strony https://www.supla.org/arduino/get-guid i wprowadź go poniżej
#define GUID {0x51,0xE9,0x36,0x14,0xD4,0xC3,0x0F,0x54,0x20,0xB6,0xA8,0x23,0x13,0x83,0x7C,0x29};

RFM69_ATC radio(D8, D2, false);
bool promiscuousMode = false;

const unsigned long period = 600000;      //Czas (10 minut) po którym bramka uznaje brak odczytu z transmitera i ustawia wartości wysyłane do Supla Cloud na 0.
double temperature = 0.0;
double humidity = 0.0;
double pressure = 0.0;
double lux = 0.0;
unsigned long startMillis = 0;
unsigned long currentMillis = 0;
unsigned long RFNodesCount = 0;

typedef struct {
  int nodeid;
  int channelNumber;
  double temperature;
  double humidity;
  double temperature2;
  double lux;
  //double batteryLevel;
  unsigned long lastContact;
} RF_TemperatureandHumidityNode;

RF_TemperatureandHumidityNode RFNodes[6];


void get_temperature_and_humidity(int channelNumber, double *temp, double *humidity) {

  for (int i = 0; i < RFNodesCount; i++)
    if (RFNodes[i].channelNumber == channelNumber)
    {
      *temp = RFNodes[i].temperature;
      *humidity = RFNodes[i].humidity;
    }
}

double get_pressure(int channelNumber, double pressure) {
   
  for (int i = 0; i < RFNodesCount; i++)
    if (RFNodes[i].channelNumber == (channelNumber-1)/2 )
    {
      pressure = RFNodes[i].temperature2; 
    }
  return  pressure;
}

double get_temperature2(int channelNumber, double lux) {

 for (int i = 0; i < RFNodesCount; i++)
    if (RFNodes[i].channelNumber == (channelNumber-1)/3 )
    {
      lux = RFNodes[i].lux; 
    }
  return  lux;
}

void setup() {
  Serial.begin(SERIAL_BAUD);
  
   SuplaDevice.setTemperatureHumidityCallback(&get_temperature_and_humidity);
   SuplaDevice.setPressureCallback(&get_pressure);
   SuplaDevice.setDistanceCallback(&get_temperature2);
   SuplaDevice.addDHT22();
   SuplaDevice.addPressureSensor();
   SuplaDevice.addDistanceSensor();
   SuplaDevice.addDHT22();
   SuplaDevice.addPressureSensor();
   SuplaDevice.addDistanceSensor();
   
   
   
  char guid[SUPLA_GUID_SIZE] = GUID;
  uint8_t mac[6] = {0x01, 0x02, 0x03, 0x04, 0x05, 0x06};
  SuplaDevice.setName("BRAMKA RB-10G2");
  SuplaDevice.begin(guid, mac, SUPLA_SERVER, LOCATION_ID, LOCATION_PASSWORD);
  
  radio.initialize(FREQUENCY,NODEID,NETWORKID);

#ifdef IS_RFM69HW_HCW
  radio.setHighPower();
#endif

  radio.encrypt(ENCRYPTKEY);
  radio.promiscuous(promiscuousMode);

  char buff[105];
  sprintf(buff, "BRAMKA RB-10G. Start komunikacji radiowej na częstotliwości %d MHz...", FREQUENCY==RF69_433MHZ ? 433 : FREQUENCY==RF69_868MHZ ? 868 : 915);
  Serial.println(buff);
}

byte ackCount = 0;
uint32_t packetCount = 0;

String getValue(String data, char separator, int index)
{
  int found = 0;
  int strIndex[] = {0, -1};
  int maxIndex = data.length() - 1;

  for (int i = 0; i <= maxIndex && found <= index; i++) {
    if (data.charAt(i) == separator || i == maxIndex) {
      found++;
      strIndex[0] = strIndex[1] + 1;
      strIndex[1] = (i == maxIndex) ? i + 1 : i;
    }
  }

  return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}

void readRadioData() {

  String value = "";
  if (radio.receiveDone())
  {
    int foundIdx = -1;

    for (int i = 0; i < RFNodesCount; i++)
      if (RFNodes[i].nodeid == radio.SENDERID)
      {
        foundIdx = i;
        break;
      }

    Serial.println("Odbieram dane...");
    if (foundIdx == -1)
    {
      if (RFNodesCount < 6)
      {
        Serial.println("Znalazłem nowy transmiter. Dodaję go do SUPLA Cloud");
        RFNodes[RFNodesCount].nodeid = radio.SENDERID;
        RFNodes[RFNodesCount].lastContact = millis();
        RFNodes[RFNodesCount].channelNumber = radio.SENDERID - 1;
        RFNodes[RFNodesCount].temperature = 0.0;
        RFNodes[RFNodesCount].humidity = 0.0;
        RFNodes[RFNodesCount].temperature2 = 0.0;
        RFNodes[RFNodesCount].lux = 0.0;
//        RFNodes[RFNodesCount].batteryLevel = 0;
        
        foundIdx = RFNodesCount;
        RFNodesCount++;
      } else {
        Serial.println("Maksymalna ilość transmiterów przekroczona!");
        foundIdx = 0;
      }
    } else
    {
      RFNodes[foundIdx].temperature = 0.0;
    }

    Serial.print("#[");
    Serial.print(++packetCount);
    Serial.print(']');
    Serial.print('['); Serial.print(radio.SENDERID, DEC); Serial.print("] ");

    value = "";
    for (byte i = 0; i < radio.DATALEN; i++)
      if (radio.DATA[i] != ' ')
        value += (char)radio.DATA[i];

    Serial.println(value);

    String tempStr = getValue(value, '|', 0);
    String humStr = getValue(value, '|', 1);
    String presStr = getValue(value, '|', 2);
    String luxStr = getValue(value, '|', 3);
    String battLevelStr = getValue(value, '|', 4);

    Serial.print("Temperatura: ");
    Serial.println(tempStr);
    Serial.print("Wilgotność: ");
    Serial.println(humStr);
    Serial.print("Ciśnienie: ");
    Serial.println(presStr);
    Serial.print("Natężenie światła: ");
    Serial.println(luxStr);
    //Serial.print("Poziom baterii: ");
    //Serial.println(battLevelStr);

    RFNodes[foundIdx].temperature = tempStr.toFloat();
    RFNodes[foundIdx].humidity = humStr.toFloat();
    RFNodes[foundIdx].temperature2 = presStr.toFloat();
    RFNodes[foundIdx].lux = luxStr.toFloat();
//    RFNodes[foundIdx].batteryLevel = battLevelStr.toFloat();
    RFNodes[foundIdx].lastContact = millis();

    Serial.print("Poziom sygnału transmitera [RX_RSSI]:"); Serial.print(radio.RSSI); Serial.print(" dBm");

    if (radio.ACKRequested())
    {
      byte theNodeID = radio.SENDERID;
      radio.sendACK();
      
      if (ackCount++ % 3 == 0)
      {
        Serial.print(" ACK TEST - Transmiter ");
        Serial.print(theNodeID);
        delay(5);
        radio.sendWithRetry(theNodeID, "ACK TEST", 8, 0);
      }
    }
    Blink(LED_BUILTIN, 100);
    Serial.println();
    Serial.println();
  }

  for (int i = 0; i < RFNodesCount; i++)
  {
    if (millis() - RFNodes[i].lastContact >= period)
    {
      RFNodes[i].temperature = -375;
      RFNodes[i].humidity = -1;
      RFNodes[i].temperature2 = -300;
      RFNodes[i].lux = 0;
//      RFNodes[i].batteryLevel = 0;
      Serial.print("Brak odczytu z czujnika ");
      Serial.println (RFNodes[i].nodeid);
    };
  }
}

void Blink(byte PIN, int DELAY_MS)
{
  pinMode(PIN, OUTPUT);
  digitalWrite(PIN,LOW);
  delay(DELAY_MS);
  digitalWrite(PIN,HIGH);
}

void loop() {
  readRadioData();
  SuplaDevice.iterate();
}

z góry bardzo dziękuję

QLQ · Post Tue Sep 22, 2020 6:43 pm

Mam ale nie ma mnie w domku. Jutro się przypomnij to podrzucę.
tak na szybko z telefonu:

Code: Select all

/*
Bramka RB-10G
Copyright (C) 2019 Robert Błaszczak

Niniejszy program jest wolnym oprogramowaniem; możesz go 
rozprowadzać dalej i/lub modyfikować na warunkach Powszechnej
Licencji Publicznej GNU, wydanej przez Fundację Wolnego
Oprogramowania - według wersji 2-giej tej Licencji lub którejś
z późniejszych wersji. 
Niniejszy program rozpowszechniany jest z nadzieją, iż będzie on 
użyteczny - jednak BEZ JAKIEJKOLWIEK GWARANCJI, nawet domyślnej 
gwarancji PRZYDATNOŚCI HANDLOWEJ albo PRZYDATNOŚCI DO OKREŚLONYCH 
ZASTOSOWAŃ. W celu uzyskania bliższych informacji - Powszechna 
Licencja Publiczna GNU. 
Z pewnością wraz z niniejszym programem otrzymałeś też egzemplarz 
Powszechnej Licencji Publicznej GNU (GNU General Public License);
jeśli nie - napisz do Free Software Foundation, Inc., 675 Mass Ave,
Cambridge, MA 02139, USA.
*/

#include <RFM69_ATC.h>                    //Pobierz z: https://github.com/lowpowerlab/rfm69

#define NODEID 1                        //Unikalny numer bramki (1 - 254).
#define NETWORKID 100                   //Numer sieci (1 - 254) w której działą bramka SUPLA oraz inne transmitery. Bramka oraz max. 6 transmiterów musi działać w sieci o takim samym ID.
#define FREQUENCY RF69_868MHZ             //Jeśli posiadasz moduł radiowy pracujący z inną częstotliwością zamień parametr na RF69_433MHZ lub RF69_915MHZ.
//#define IS_RFM69HW_HCW                  //Usuń zacznik komentarza, jeśli posiadasz moduł radiowy w wersji RFM69HW/HCW.
#define ENCRYPTKEY "qwertyuiopasdfgh"     //Klucz kodowania - 16 znaków (ani mniej, ani więcej) - identyczny w bramce SUPLA i we wszystkich transmiterach.
#define ENABLE_ATC                        //Wstaw znacznik komentarza jeśli chcesz wyłączyć automatyczną kontrolę transmisji (ATC).

#define SERIAL_BAUD 115200                //Prędkość transmisji portu szeregowego.

#define SUPLADEVICE_CPP
#include <SuplaDevice.h>
#include <DallasTemperature.h>
OneWire oneWire(2); //  - Pin number
DallasTemperature sensors(&oneWire);

#define SUPLA_SERVER "svr5.supla.org"
#define LOCATION_ID 789
#define LOCATION_PASSWORD "ae15"
// pobierz identyfikator urządzenia ze strony https://www.supla.org/arduino/get-guid i wprowadź go poniżej
#define GUID {0x4D,0x88,0xF6,0x46,0x25,0xAD,0xF5,0x75,0xB0,0x69,0x8C,0x94,0x12,0x41,0xBB,0x8C};

RFM69_ATC radio(D8, D2, false);
bool promiscuousMode = false;

const unsigned long period = 120000;      //Czas (2 minut) po którym bramka uznaje brak odczytu z transmitera i ustawia wartości wysyłane do Supla Cloud na 0.
double temperature = 0.0;
double humidity = 0.0;
double pressure = 0.0;
double lux = 0.0;
double wind = 0.0;
unsigned long startMillis = 0;
unsigned long currentMillis = 0;
unsigned long RFNodesCount = 0;

typedef struct {
  int nodeid;
  int channelNumber;
  double temperature;
  double humidity;
  double pressure;
  double lux;
  double wind;
  double batteryLevel;
  unsigned long lastContact;
              } RF_TemperatureandHumidityNode;

  RF_TemperatureandHumidityNode RFNodes[6];

//########################### temperatra i wilgotnosc BME280 ###############################

void get_temperature_and_humidity(int channelNumber, double *temp, double *humidity) {

//    if (RFNodes[1].channelNumber == (channelNumber))
//    {
      *temp = RFNodes[0].temperature;
      *humidity = RFNodes[0].humidity;
  //  }
}
//########################### cisnienie BME280  ############################################

double get_pressure(int channelNumber, double pressure) {
  return RFNodes[0].pressure;
}
//########################### natezenie swiatła BH1750 ######################################

double get_temperature(int channelNumber, double lux) {
  return RFNodes[0].lux;
//double get_distance(int channelNumber, double lux) {
//  return RFNodes[0].lux;
}
//########################### wiatr anenometr Hall ##########################################

double get_wind(int channelNumber, double wind) {
  return  RFNodes[1].wind;
}
//##################################### SETUP ###############################################

void setup() {
  Serial.begin(SERIAL_BAUD);
  
   SuplaDevice.setTemperatureHumidityCallback(&get_temperature_and_humidity);
   SuplaDevice.setPressureCallback(&get_pressure);
   //SuplaDevice.setDistanceCallback(&get_distance);    // zrobione zamiast na odległości to na temp na ds18
   SuplaDevice.setTemperatureCallback(&get_temperature);
   SuplaDevice.setWindCallback(&get_wind);
   SuplaDevice.addDHT22();
   SuplaDevice.addPressureSensor();
  // SuplaDevice.addDistanceSensor(); // zrobione zamiast na odległości to na temp na ds18 - poniżej
   SuplaDevice.addDS18B20Thermometer();
   SuplaDevice.addWindSensor();
 
   
   
   
  char guid[SUPLA_GUID_SIZE] = GUID;
  uint8_t mac[6] = {0x01, 0x02, 0x03, 0x04, 0x05, 0x06};
  SuplaDevice.setName("BRAMKA POG_FIRM");
  SuplaDevice.begin(guid, mac, SUPLA_SERVER, LOCATION_ID, LOCATION_PASSWORD);
  
  radio.initialize(FREQUENCY,NODEID,NETWORKID);

#ifdef IS_RFM69HW_HCW
  radio.setHighPower();
#endif

  radio.encrypt(ENCRYPTKEY);
  radio.promiscuous(promiscuousMode);

  char buff[105];
  sprintf(buff, "BRAMKA RB-10G. Start komunikacji radiowej na częstotliwości %d MHz...", FREQUENCY==RF69_433MHZ ? 433 : FREQUENCY==RF69_868MHZ ? 868 : 915);
  Serial.println(buff);
}

//################################  SETUP END ###########################################################  
byte ackCount = 0;
uint32_t packetCount = 0;

String getValue(String data, char separator, int index)
{
  int found = 0;
  int strIndex[] = {0, -1};
  int maxIndex = data.length() - 1;

  for (int i = 0; i <= maxIndex && found <= index; i++) {
    if (data.charAt(i) == separator || i == maxIndex) {
      found++;
      strIndex[0] = strIndex[1] + 1;
      strIndex[1] = (i == maxIndex) ? i + 1 : i;
    }
  }

  return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}

void readRadioData() {

  String value = "";
  if (radio.receiveDone())
  {
    int foundIdx = -1;

    for (int i = 0; i < RFNodesCount; i++)
      if (RFNodes[i].nodeid == radio.SENDERID)
      {
        foundIdx = i;
        break;
      }

    Serial.println("Odbieram dane...");
    if (foundIdx == -1)
    {
      if (RFNodesCount < 6)
      {
        Serial.println("Znalazłem nowy transmiter. Dodaję go do SUPLA Cloud");
        RFNodes[RFNodesCount].nodeid = radio.SENDERID;
        RFNodes[RFNodesCount].lastContact = millis();
        RFNodes[RFNodesCount].channelNumber = radio.SENDERID - 1;
        RFNodes[RFNodesCount].temperature = 0.0;
        RFNodes[RFNodesCount].humidity = 0.0;
        RFNodes[RFNodesCount].pressure = 0.0;
        RFNodes[RFNodesCount].lux = 0.0;
        RFNodes[RFNodesCount].wind = 0.0;
        RFNodes[RFNodesCount].batteryLevel = 0;
        
        foundIdx = RFNodesCount;
        RFNodesCount++;
      } else {
        Serial.println("Maksymalna ilość transmiterów przekroczona!");
        foundIdx = 0;
      }
    } else
    {
      RFNodes[foundIdx].temperature = 0.0;
    }

    Serial.print("#[");
    Serial.print(++packetCount);
    Serial.print(']');
    Serial.print('['); Serial.print(radio.SENDERID, DEC); Serial.print("] ");

    value = "";
    for (byte i = 0; i < radio.DATALEN; i++)
      if (radio.DATA[i] != ' ')
        value += (char)radio.DATA[i];

    Serial.println(value);

    String tempStr = getValue(value, '|', 0);
    String humStr = getValue(value, '|', 1);
    String presStr = getValue(value, '|', 2);
    String luxStr = getValue(value, '|', 3);
    String windStr = getValue(value, '|', 4);
    String battLevelStr = getValue(value, '|', 5);

    Serial.print("Temperatura: ");
    Serial.println(tempStr);
    Serial.print("Wilgotność: ");
    Serial.println(humStr);
    Serial.print("Ciśnienie: ");
    Serial.println(presStr);
    Serial.print("Natężenie światła: ");
    Serial.println(luxStr);
    Serial.print("Prędkość wiatru: ");
    Serial.println(windStr);
    Serial.print("Poziom baterii: ");
    Serial.println(battLevelStr);

    RFNodes[foundIdx].temperature = tempStr.toFloat();
    RFNodes[foundIdx].humidity = humStr.toFloat();
    RFNodes[foundIdx].pressure = presStr.toFloat();
    RFNodes[foundIdx].lux = luxStr.toFloat();
    RFNodes[foundIdx].wind = windStr.toFloat();
    RFNodes[foundIdx].batteryLevel = battLevelStr.toFloat();
    RFNodes[foundIdx].lastContact = millis();

    Serial.print("Poziom sygnału transmitera [RX_RSSI]:"); Serial.print(radio.RSSI); Serial.print(" dBm");

    if (radio.ACKRequested())
    {
      byte theNodeID = radio.SENDERID;
      radio.sendACK();
      
      if (ackCount++ % 3 == 0)
      {
        Serial.print(" ACK TEST - Transmiter ");
        Serial.print(theNodeID);
        delay(5);
        radio.sendWithRetry(theNodeID, "ACK TEST", 8, 0);
      }
    }
    Blink(LED_BUILTIN, 100);
    Serial.println();
    Serial.println();
  }

  for (int i = 0; i < RFNodesCount; i++)
  {
    if (millis() - RFNodes[i].lastContact >= period)
    {
      RFNodes[i].temperature = -375;
      RFNodes[i].humidity = -1;
      RFNodes[i].pressure = -10;
      RFNodes[i].lux = 0;
      RFNodes[i].wind = 0;
      RFNodes[i].batteryLevel = 0;
      Serial.print("Brak odczytu z czujnika ");
      Serial.println (RFNodes[i].nodeid);
    };
  }
}

void Blink(byte PIN, int DELAY_MS)
{
  pinMode(PIN, OUTPUT);
  digitalWrite(PIN,LOW);
  delay(DELAY_MS);
  digitalWrite(PIN,HIGH);
}

void loop() {
  readRadioData();
  SuplaDevice.iterate();
}

dogu18 · Post Tue Sep 22, 2020 7:51 pm

Super. Dzięki działają idealnie